* Transformació de les dades del fitxer de "DATOS DE EMPLEADOS.SAV".

GET FILE='Datos de empleados.sav'.

*Recodificació de valors (variable numèrica).
FRE SALARIO.
RECODE SALARIO (LO THRU 25000=1) (25001 THRU 35000=2) (35001 THRU HI=3) INTO SALARIO2.
VAR LAB SALARIO2 "Nivel de salario".
VAL LAB SALARIO2 1 '15750-25000' 2 '25000-35000' 3 '35000-135000'.
FORMATS SALARIO2(F1.0).
FRE SALARIO2.

* Recodificació de valors (variable cadena).
RECODE SEXO ('h'=1)('m'=2) INTO SEXO2.
FORMATS SEXO2(F1.0).
VAR LAB SEXO2 "Sexo empleado/a".
VAL LAB SEXO2 1 'Home' 2 'Dona'.
FRE SEXO2.

* Recodificació de valors (recodificació automàtica).
AUTORECODE VARIABLES=sexo  /INTO sexo3
  /PRINT.

*Cálcul de variables i recodificació de valors.
FRE FECHNAC.
COMPUTE EDAD=1994-XDATE.YEAR(FECHNAC).
VAR LAB EDAD 'Edad empleado'.
FORMAT EDAD(F2.0).
FRE EDAD.

RECODE EDAD (LO THRU 30=1)(31 THRU 40=2)(41 THRU 50=3)(51 THRU HI=4) INTO EDAD2.
VAR LAB EDAD2 'EDAD EMPLEADO EN INTERVALOS'.
VAL LAB EDAD2 1 'HASTA 30' 2 '31-40' 3 '41-50' 4 'MAS DE 50'.
FORMATS EDAD2 (F1.0).
FRE EDAD2.

* Crear una variable a partir de comptar aparicions.
DATA LIST FREE /ORDINADO INTERNET DVD MOBIL.
BEGIN DATA.
0 0 0 0
1 0 1 1
1 1 1 1
0 0 0 1
1 1 0 1
1 1 1 1
0 0 1 1
END DATA.
COUNT X=ORDINADO INTERNET DVD MOBIL (1).
FRE X.

*Generació d'una variable a partir d'altres amb IF.
CROSS CATLAB BY SEXO2.
IF (SEXO2=1 AND CATLAB=1) SEXCAT=1.
IF (SEXO2=1 AND CATLAB=2) SEXCAT=2.
IF (SEXO2=1 AND CATLAB=3) SEXCAT=3.
IF (SEXO2=2 AND CATLAB=1) SEXCAT=4.
IF (SEXO2=2 AND CATLAB=2) SEXCAT=5.
IF (SEXO2=2 AND CATLAB=3) SEXCAT=6.
VAR LAB SEXCAT 'SEXO Y CATEGORIA'.
VAL LAB SEXCAT 1 'Administrativo' 2 'Hombre seguridad' 3 'Directivo' 4 'Administrativa' 5 'Mujer seguridad' 6 'Directiva'. 
FORMAT SEXCAT(F1.0).
FRE SEXCAT.

*Generació de variables amb l'estructura DO IF ...END IF.
DO IF (SEXO2=1).
IF (CATLAB=1) SEXCAT2=1.
IF (CATLAB=2) SEXCAT2=2.
IF (CATLAB=3) SEXCAT2=3.
ELSE IF (SEXO2=2).
IF (CATLAB=1) SEXCAT2=4.
IF (CATLAB=2) SEXCAT2=5.
IF (CATLAB=3) SEXCAT2=6.
END IF.
VAR LAB SEXCAT2 'SEXO Y CATEGORIA 2'.
VAL LAB SEXCAT2 1 'Administrativo' 2 'Hombre seguridad' 3 'Directivo' 4 'Administrativa' 5 'Mujer seguridad' 6 'Directiva'. 
FORMAT SEXCAT2(F1.0).
FRE SEXCAT2.

*Generació de variables amb l'estructura DO IF ...END IF.
DO IF (SEXO2=1).
+ DO IF (CATLAB=1).
+ COMPUTE SEXCAT3=1.
+ ELSE IF (CATLAB=2).
+ COMPUTE SEXCAT3=2.
+ ELSE.
+ COMPUTE SEXCAT3=3.
+ END IF.
ELSE IF (CATLAB=1).
COMPUTE SEXCAT3=4.
ELSE IF (CATLAB=2).
COMPUTE SEXCAT3=5.
ELSE.
COMPUTE SEXCAT3=6.
END IF.
VAR LAB SEXCAT3 'SEXO Y CATEGORIA 3'.
VAL LAB SEXCAT3 1 'Administrativo' 2 'Hombre seguridad' 3 'Directivo' 4 'Administrativa' 5 'Mujer seguridad' 6 'Directiva'. 
FORMAT SEXCAT3(F1.0).
FRE SEXCAT3.