TITLE Taules de contingčncia, anālisi logarítmica lineal i anālisi de correspondčncies.

*** Generaciķ i identificaciķ de les dades d'una taula de contingčncia.

DATA LIST FREE/ EST ACT SEX FRE.

BEGIN DATA
1 1 1 72
1 2 1 47
2 1 1 110
2 2 1 196
3 1 1 44
3 2 1 179
1 1 2 86
1 2 2 38
2 1 2 173
2 2 2 283
3 1 2 28
3 2 2 187
END DATA.

VAR LAB EST "Nivell d'estudis"
                ACT 'Actitud: permančncia de la dona a la llar'
                SEX 'Sexe'.
VAL LAB EST 1 'Primaris' 2 'Secundaris' 3 'Superiors' /
                ACT 1 "D'acord" 2 "En desacord" /
                SEX  1 'Home' 2 'Dona'.

FORMAT EST ACT SEX (F1.0).
WEIGHT BY FRE.

CROSSTABS ACT  BY EST SEX /EST  BY SEX /ACT  BY EST  BY SEX
    /STATISTICS=CHISQ PHI CC
    /CELLS= COUNT EXPECTED COLUMN ASRESID
    /BARCHART .

* Anālisi Log-lineal jerārquic: selecciķ de model.

HILOGLINEAR  ACT(1 2) EST(1 3) SEX(1 2)  
  /METHOD=BACKWARD
  /CRITERIA MAXSTEPS(10) P(.05) ITERATION(20) DELTA(.5)
  /PRINT=ASSOCIATION
  /DESIGN .

* Anālisi Log-lineal: general.

* Procediment antic.
LOGLINEAR  ACT(1 2) EST(1 3) SEX(1 2)  
  /PRINT=FREQ RESID ESTIM
  /PLOT=RESID NORMPROB
  /DESIGN=ACT BY EST
                 EST BY SEX
                 ACT EST SEX.

* Procediment actual.
GENLOG
  EST ACT SEX
  /MODEL = POISSON
  /PRINT = FREQ RESID ADJRESID ZRESID DEV DESIGN ESTIM CORR COV
  /PLOT = RESID( ADJRESID ) NORMPROB( ADJRESID )
  /CRITERIA = CIN(95) ITERATE(20) CONVERGE(.001) DELTA(.5)
  /DESIGN ACT EST SEX ACT*EST EST*SEX .


* Generaciķ i identificaciķ de les dades. Procediment alternatiu.

INPUT PROGRAM.
LOOP #I=1 TO 1443.
IF (#I LE 72)  EST=1.
IF (#I LE 72)  ACT=1.
IF (#I LE 72)  SEX=1.
IF (#I GT 72 AND #I LE 119) EST=1.
IF (#I GT 72 AND #I LE 119) ACT=2.
IF (#I GT 72 AND #I LE 119) SEX=1.
IF (#I GT 119 AND #I LE 229) EST=2.
IF (#I GT 119 AND #I LE 229) ACT=1.
IF (#I GT 119 AND #I LE 229) SEX=1.
IF (#I GT 229 AND #I LE 425) EST=2.
IF (#I GT 229 AND #I LE 425) ACT=2.
IF (#I GT 229 AND #I LE 425) SEX=1.
IF (#I GT 425 AND #I LE 469) EST=3.
IF (#I GT 425 AND #I LE 469) ACT=1.
IF (#I GT 425 AND #I LE 469) SEX=1.
IF (#I GT 469 AND #I LE 648) EST=3.
IF (#I GT 469 AND #I LE 648) ACT=2.
IF (#I GT 469 AND #I LE 648) SEX=1.
IF (#I GT  648 AND #I LE 734) EST=1.
IF (#I GT 648 AND #I LE 734) ACT=1.
IF (#I GT 648 AND #I LE 734) SEX=2.
IF (#I GT 734 AND #I LE 772) EST=1.
IF (#I GT 734 AND #I LE 772) ACT=2.
IF (#I GT 734 AND #I LE 772) SEX=2.
IF (#I GT 772 AND #I LE 945) EST=2.
IF (#I GT 772 AND #I LE 945) ACT=1.
IF (#I GT 772 AND #I LE 945) SEX=2.
IF (#I GT 945 AND #I LE 1228) EST=2.
IF (#I GT 945 AND #I LE 1228) ACT=2.
IF (#I GT 945 AND #I LE 1228) SEX=2.
IF (#I GT 1228 AND #I LE 1256) EST=3.
IF (#I GT 1228 AND #I LE 1256) ACT=1.
IF (#I GT 1228 AND #I LE 1256) SEX=2.
IF (#I GT 1256 AND #I LE 1443) EST=3.
IF (#I GT 1256 AND #I LE 1443) ACT=2.
IF (#I GT 1256 AND #I LE 1443) SEX=2.
END CASE.
END LOOP.
END FILE.
END INPUT PROGRAM.

VAR LAB EST "Nivell d'estudis"
                ACT 'Actitud: permančncia de la dona a la llar'
                SEX 'Sexe'.
VAL LAB EST 1 'Primaris' 2 'Secundaris' 3 'Superiors' /
                ACT 1 "D'acord" 2 "En desacord" /
                SEX  1 'Home' 2 'Dona'.

FORMAT EST ACT SEX (F1.0).

CROSSTABS ACT  BY EST  BY SEX
    /CELLS= COUNT EXPECTED COLUMN ASRESID.

* Anālisi de correspondčncies múltiples.

HOMALS
  /VARIABLES=act(2) est(3) sex(2)
  /ANALYSIS=act  est  sex
  /DIMENSION=2
  /PRINT FREQ EIGEN QUANT
  /PLOT QUANT NDIM(ALL,MAX).

MULTIPLE CORRES
  VARIABLES=EST ACT SEX
  /ANALYSIS=EST(WEIGHT=1) ACT(WEIGHT=1) SEX(WEIGHT=1)
  /MISSING=EST(PASSIVE,MODEIMPU) ACT(PASSIVE,MODEIMPU) SEX(PASSIVE,MODEIMPU)
  /DIMENSION=2
  /NORMALIZATION=VPRINCIPAL
  /MAXITER=100
  /CRITITER=.00001
  /PRINT=CORR DISCRIM
  /PLOT=JOINTCAT( EST ACT SEX ) (20) DISCRIM(20) .