* Aquest exercici prāctic estā destinat a l'anālisi de taules de contingčncia a partir 
d'un exemple publicat a un article de la revista Papers:

LATIESA, Margarita (1991). ĢIntroducciķ a los modelos logarítmicos linealesģ. 
                            Papers. Revista de Sociologia 37. P. 97-112.

A l'exemple es relacionen tres variables: l'abandonament dels estudis universitaris,
l'activitat laboral i l'horari, a partir d'un total de 474 casos. Les instruccions
que segueixen permeten analitzar la relaciķ entre aquestes variables a partir de la 
lectura dels percentatges, el cālcul d'estadístics d'associaciķ, mitjanįant l'anālisi
logarítmica lineal i l'anālisi de correspondčncies.


* Generaciķ i identificaciķ de les dades de la taula de contingčncia.

DATA LIST FREE/ ABA ACT HOR FRE.

BEGIN DATA
1 1 1 100
1 1 2 70
1 1 3 75
1 2 1 17 
1 2 2 50
1 2 3 55
2 1 1 10
2 1 2 25
2 1 3 10
2 2 1 7
2 2 2 20
2 2 3 35
END DATA.

VAR LAB ABA 'Abandonament dels estudis universitaris'
        ACT 'Activitat laboral'
        HOR 'Horari'.
VAL LAB ABA ACT 1 'No' 2 'Sí'/
            HOR 1 'Matí' 2 'Tarda' 3 'Nit'.

FORMAT ABA ACT HOR (F1.0).
WEIGHT BY FRE.

FREQ VAR=ALL.

* Taules de contingčncia bivariables i trivariables.

CROSSTABS ABA BY ACT /ABA BY HOR /HOR BY ACT 
         /ABA BY ACT BY HOR  
 /CELLS=ALL
 /STATISTICS=ALL.

* Anālisi log-lineal jerārquica amb dues i tres variables.

HILOGLINEAR ABA ACT(1,2)
 /PRINT=ALL
 /DESIGN=ABA*ACT.

HILOGLINEAR ABA ACT(1,2) HOR(1,3)
 /PRINT=ALL
 /METHOD=BACKWARD
 /DESIGN=ABA*ACT*HOR.

* Estimaciķ parāmetres model saturat.

LOGLINEAR ABA ACT(1,2) HOR(1,3)
 /PRINT=ESTIM
 /DESIGN.

GENLOG
  ABA ACT HOR
  /MODEL = POISSON
  /PRINT = FREQ RESID ADJRESID ZRESID DEV DESIGN ESTIM CORR COV ITERATION
  /PLOT = RESID( ADJRESID DEV ) NORMPROB( ADJRESID DEV )
  /CRITERIA = CIN(95) ITERATE(20) CONVERGE(.001) DELTA(.5)
  /DESIGN.


* Anālisi log-lineal jerārquica amb el model no saturat de classe generadora:
  [ABA ACT]  [ACT HOR]
 
HILOGLINEAR
  ABA(1 2) ACT(1 2) HOR(1 3)  /METHOD=BACKWARD
  /CRITERIA MAXSTEPS(10) P(.05) ITERATION(20) DELTA(.5)
  /PRINT=FREQ RESID
  /PLOT=RESID NORMPROB
  /DESIGN ABA*ACT ACT*HOR  .

* Estimaciķ dels parāmetres del model no saturat de classe generadora:
  [ABA ACT]  [ACT HOR]

LOGLINEAR ABA ACT(1,2) HOR(1,3)
 /PRINT=ESTIM
 /DESIGN=ABA BY ACT 
         ACT BY HOR 
         ABA 
         ACT 
         HOR.

GENLOG
  ABA ACT HOR
  /MODEL = POISSON
  /PRINT = FREQ RESID ADJRESID ZRESID DEV DESIGN ESTIM CORR COV ITERATION
  /PLOT = RESID( ADJRESID DEV ) NORMPROB( ADJRESID DEV )
  /CRITERIA = CIN(95) ITERATE(20) CONVERGE(.001) DELTA(.5)
  /DESIGN ABA ACT HOR ABA*ACT ACT*HOR  .


* Anālisi de correspondčncies múltiple.

MULTIPLE CORRES
  VARIABLES=ABA ACT HOR
  /ANALYSIS=ABA(WEIGHT=1) ACT(WEIGHT=1) HOR(WEIGHT=1)
  /MISSING=ABA(PASSIVE,MODEIMPU) ACT(PASSIVE,MODEIMPU) HOR(PASSIVE,MODEIMPU)
  /DIMENSION=2
  /NORMALIZATION=VPRINCIPAL
  /MAXITER=100
  /CRITITER=.00001
  /PRINT=CORR DISCRIM
  /PLOT=OBJECT (20) JOINTCAT( ABA ACT HOR ) (20) DISCRIM(20) .