***** Anàlisi Log-lineal LOGIT.
*** Exemple utilizat a: JJ. Sánchez Carrión (1984). Introducción a las técnicas de análisis multivariable. Madrid: CIS. Capítol 11.
* Les dades procedeixen d'una investigació sobre immigrants llatinoamericans a España del 1981, realitzat per G.Lutz i  M.Roiz.
* Es considera una mostra aleatòria simple de 396 persones amb la informació de 4 variables: estudis, antiguitat, permís i ingressos.


*** Identificació de les dades.

DATA LIST FREE /E A P I FRE.

VAR LAB E 'Estudis'
                  A 'Antiguitat'
                  P 'Permís de treball'
                   I 'Ingressos'.
VAL LAB E  1 'Inferiors'  2 'Superiors'  
                 /A  1 '1960-70'  2 '1971-77' 3 '1978-80'
                 /P  1 'No' 2 'Sí'
                  /I  1 'Baixos' 2 'Alts'.    
FORMAT E A P I (F1.0).

BEGIN DATA
1 1 1 1 10
1 1 1 2 7
1 1 2 1 2
1 1 2 2 3
1 2 1 1 39
1 2 1 2 9
1 2 2 1 15
1 2 2 2 14
1 3 1 1 75
1 3 1 2 10
1 3 2 1 18
1 3 2 2 8
2 1 1 1 7
2 1 1 2 6
2 1 2 1 2
2 1 2 2 12
2 2 1 1 23
2 2 1 2 19
2 2 2 1 22
2 2 2 2 22
2 3 1 1 43
2 3 1 2 6
2 3 2 1 12
2 3 2 2 12
END DATA.

WEIGHT BY FRE.

* Tablas personalizadas.
CTABLES
  /VLABELS VARIABLES=I E A P DISPLAY=DEFAULT
  /TABLE E [C] > A [C] > P [C][COUNT F40.0] BY I [C]
  /CATEGORIES VARIABLES=I E A P ORDER=A KEY=VALUE EMPTY=INCLUDE.


*** 1. Model LOGIT amb dues variables (VD dicotòmica).

CROSSTABS I BY E /CELLS=COUNT COL.

HILOGLINEAR
  I(1 2) E(1 2)  /METHOD=BACKWARD
  /CRITERIA MAXSTEPS(10) P(.05) ITERATION(20) DELTA(.5)
  /PRINT=FREQ RESID ASSOCIATION ESTIM
  /DESIGN .

LOGLINEAR I(1,2) E(1,2)
 /PRINT=ALL 
 /PLOT RESID NORMPROB
 /DESIGN.

GENLOG
  I  BY E
  /MODEL = MULTINOMIAL
  /PRINT = FREQ RESID ADJRESID ZRESID DEV DESIGN ESTIM CORR COV ITERATION
  /CRITERIA = CIN(95) ITERATE(20) CONVERGE(.001) DELTA(.5)
  /DESIGN .


*** 2. Model LOGIT amb 4 variables (Model de dependència simple).

CROSSTABS I BY E BY A BY P /CELLS=COUNT COL.

* Determinació del model més parsimoniòs.
HILOGLINEAR  I(1 2) E(1 2) P(1 2) A(1 3) 
  /METHOD=BACKWARD
  /CRITERIA MAXSTEPS(10) P(.05) ITERATION(20) DELTA(.5)
  /PRINT=FREQ RESID ASSOCIATION
  /DESIGN .

LOGLINEAR I(1 2) BY E(1 2) P(1 2) A(1 3) 
 /PRINT=ALL 
 /PLOT RESID NORMPROB
 /DESIGN=I   I BY E   I BY P  I BY A.

* Model logit amb la constant.
GENLOG
  I  BY E P A
  /MODEL = MULTINOMIAL
  /PRINT = FREQ RESID ADJRESID ZRESID DEV DESIGN ESTIM CORR COV ITERATION
  /PLOT = RESID( ADJRESID DEV ) NORMPROB( ADJRESID DEV )
  /CRITERIA = CIN(95) ITERATE(20) CONVERGE(.001) DELTA(.5)
  /DESIGN  I  I*E  I*P  I*A.

* Model logit sense la constant.
GENLOG
  I  BY E P A
  /MODEL = MULTINOMIAL
  /PRINT = FREQ RESID ADJRESID ZRESID DEV DESIGN ESTIM CORR COV ITERATION
  /PLOT = RESID( ADJRESID DEV ) NORMPROB( ADJRESID DEV )
  /CRITERIA = CIN(95) ITERATE(20) CONVERGE(.001) DELTA(.5)
  /DESIGN  I*E  I*P  I*A.

*** 3. Model LOGIT amb 4 variables (Model de dependència complex).

* 1a. equació.
LOGLINEAR E(1,2) BY A(1,3)
 /PRINT=ESTIM
 /DESIGN E  E BY A.

GENLOG
  E  BY A
  /MODEL = MULTINOMIAL
  /PRINT = FREQ RESID ADJRESID ZRESID DEV DESIGN ESTIM CORR COV ITERATION
  /CRITERIA = CIN(95) ITERATE(20) CONVERGE(.001) DELTA(.5)
  /DESIGN .

* 2a. equació.
LOGLINEAR P(1,2) BY E(1,2) A(1,3) 
 /PRINT=ESTIM
 /DESIGN   P  P BY E  P BY A.

GENLOG
  P  BY E A
  /MODEL = MULTINOMIAL
  /PRINT = FREQ RESID ADJRESID ZRESID DEV DESIGN ESTIM CORR COV ITERATION
  /PLOT = RESID( ADJRESID DEV ) NORMPROB( ADJRESID DEV )
  /CRITERIA = CIN(95) ITERATE(20) CONVERGE(.001) DELTA(.5)
  /DESIGN P P*E P*A   .

* 3a. equació: la mateixa de l'apartat 2 anterior.