*************************************************************
 Programa d'instruccions d'SPSS per al tractament de fitxers.
*************************************************************

GET FILE='Datos de empleados.sav'.

* Ordenar casos d'un fitxer.
SORT CASES BY fechnac (A).
SORT CASES BY sexo (A) minoría (D).

* Segmentar un fitxer.
SORT CASES BY sexo.
SPLIT FILE LAYERED BY sexo.
FRE educ.
SPLIT FILE SEPARATE BY sexo.
FRE educ.
* Desactivar la segmentació.
SPLIT FILE OFF.

* Selecció filtrada de casos (empleats directius).
USE ALL.
COMPUTE filter_$=(catlab = 3).
VARIABLE LABEL filter_$ 'catlab = 3 (FILTER)'.
VALUE LABELS filter_$  0 'No seleccionado' 1 'Seleccionado'.
FORMAT filter_$ (f1.0).
FILTER BY filter_$.
EXECUTE.

* Anul·lació de la selecció filtrada o selecció de nou de tots els casos.
FILTER OFF.
USE ALL.
EXECUTE .

* Selecció estricta de casos (empleats directius).
FILTER OFF.
USE ALL.
SELECT IF(catlab = 3).
EXECUTE .

GET FILE='Datos de empleados.sav'.

* Selecció temporal amb SELECT IF i TEMPORARY.
TEMPORARY.
SELECT IF(catlab = 3).
FRE sexo.
FRE sexo.

* Selecció filtrada temporal a través de la variable MINORÍA.
USE ALL.
FILTER BY minoría .
EXECUTE .

* Selecció d'una mostra del 10% de casos.
FILTER OFF.
USE ALL.
SAMPLE .10.
EXECUTE.

* Selecció d'una mostra de 100 casos del total de 474.
FILTER OFF.
USE ALL.
SAMPLE 100 from  474.
EXECUTE .

* Selecció d'un rang de casos, des de l'1 fins el 100 (temporalment).
FILTER OFF.
use  1 thru  100  .
EXECUTE .

* Selecció d'un rang de casos, des de l'1 fins el 100 (permanentment).
FILTER OFF.
use  1 thru  100 /permanent .
EXECUTE .

* Ponderació de casos (ponderació de la mostra).
FRE sexo.
IF sexo='h' PES=0.9186.
IF sexo='m' PES=1.0972.
FRE pes.
WEIGHT BY PES.
FRE sexo.
* Desactivar la ponderació de casos.
WEIGHT OFF.

* Ponderació de casos (reproducció d'una taula de contingència).
CROSS minoría BY sexo.
DATA LIST FREE /minoría sexo fre.
BEGIN DATA.
1 1 194
1 2 176
2 1 64
2 2 40
END DATA.
WEIGHT BY fre.
CROSS minoría BY sexo.

* Agregació de les dades.
AGGREGATE /OUTFILE='aggr.sav'
  /BREAK=sexo
  /salari_1 'Mitjana salari actual' = MEAN(salario) 
  /salini_1 'Mitjana salari inicial' = MEAN(salini) 
  /tiempe_1 'Mitjana temps empresa' = MEAN(tiempemp)
  /exppre_1 'Mitjana experiència' = MEAN(expprev) 
  /educ_1 'Mitjana educació' =  MEAN(educ)
  /casos=N.
GET FILE='aggr.sav'.
LIST.

GET FILE='Datos de empleados.sav'.

* Transposar una matriu de dades.
FLIP VARIABLES=sexo id fechnac educ catlab salario salini tiempemp expprev minoría.

*Fusió de fitxers: afegir variables.
GET FILE='Datos de empleados A.sav'.
MATCH FILES /FILE=*
 /FILE='Datos de empleados B.sav'
 /IN=origen01
 /BY id.
VARIABLE LABELS origen01
 'El origen del caso es ... Datos de empleados B.sav'.
EXECUTE.

*Fusió de fitxers: afegir casos.
GET FILE='Datos de empleados 1-200.sav'.
ADD FILES /FILE=*
 /FILE='Datos de empleados 201-474.sav'
 /IN=origen01.
VARIABLE LABELS origen01
 'El origen del caso es ...Datos de empleados 201-474.sav'.
EXECUTE.