* Anàlisi de regressió simple i múltiple.
* Exemples de:
* SANCHEZ CARRION, J.J. (1999). Manual de análisis estadístico de los datos. Madrid: Alianza. Manuales, 055.

GET FILE='mundo61.sav'.

GRAPH
  /SCATTERPLOT(BIVAR)=pnb WITH tbn  BY pais (IDENTIFY)
  /MISSING=LISTWISE .

REGRESSION
  /DESCRIPTIVES MEAN STDDEV CORR SIG N
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS R ANOVA
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN
  /DEPENDENT tbn
  /METHOD=ENTER pnb.

** Detecció de casos anòmals.
REGRESSION
  /DEPENDENT tbn
  /METHOD=ENTER pnb
  /CASEWISE PLOT(zresid) OUTLIERS (2)
  /RESIDUAL=id(pais).

** Eliminació del cas 15 d'Arabia Saudí.
USE ALL.
COMPUTE filter_$=($CASENUM NE 15).
VARIABLE LABEL filter_$ '$CASENUM NE 15 (FILTER)'.
VALUE LABELS filter_$  0 'No seleccionado' 1 'Seleccionado'.
FORMAT filter_$ (f1.0).
FILTER BY filter_$.
EXECUTE.

GRAPH
  /SCATTERPLOT(BIVAR)=pnb WITH tbn BY pais (IDENTIFY)
  /MISSING=LISTWISE .

REGRESSION
  /DESCRIPTIVES MEAN STDDEV CORR SIG N
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS R ANOVA
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN
  /DEPENDENT tbn
  /METHOD=ENTER pnb.

COMPUTE PNBLOG=LG10(PNB).
GRAPH
  /SCATTERPLOT(BIVAR)=pnblog WITH tbn  BY pais (IDENTIFY)
  /MISSING=LISTWISE .

REGRESSION
  /DEPENDENT tbn
  /METHOD=ENTER pnblog
  /CASEWISE PLOT(zresid) OUTLIERS (2)
  /RESIDUAL=id(pais).

* Supuestos y representaciones no hechas por SCarrión.
REGRESSION
  /DESCRIPTIVES MEAN STDDEV CORR SIG N
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS R ANOVA
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN
  /DEPENDENT tbn
  /METHOD=ENTER pnblog
  /RESIDUALS HIST(ZRESID) NORM(ZRESID) /* Normalidad */
  /CASEWISE PLOT(ZRESID) ALL           /* Autocorrelación */
  /SCATTERPLOT=(*ZRESID,*ZPRED)        /* Linealidad */
               (*ZRESID,pnblog)        /* Heterocedasticidad */.


** REGRESSION MULTIPLE.

GRAPH
  /SCATTERPLOT(XYZ)=pnblog WITH tbn WITH analfabe BY pais (IDENTIFY)
  /MISSING=LISTWISE.

CORRELATIONS
  /VARIABLES=tbn pnblog analfabe
  /PRINT=TWOTAIL NOSIG
  /MISSING=PAIRWISE .

REGRESSION
  /DESCRIPTIVES MEAN STDDEV CORR SIG N
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS R ANOVA
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN
  /DEPENDENT tbn
  /METHOD=ENTER pnblog analfabe.

** REGRESION CON VARIABLES FICTICIAS.

FILTER OFF.
USE ALL.
EXECUTE.

COMPUTE CONTINEN=$CASENUM.
RECODE CONTINEN (1 THRU 13=1)(14 THRU 34,61=2)(35 THRU 44=3)(45 THRU 60=4).
VAR LAB CONTINEN 'Continente'.
VAL LAB CONTINEN 1 'Africa' 2 'Asia' 3 'América' 4 'Europa'.
IF (CONTINEN=1) AFRICA=1.
IF (CONTINEN NE 1) AFRICA=0.
IF (CONTINEN=2) ASIA=1.
IF (CONTINEN NE 2) ASIA=0.
IF (CONTINEN=3) AMERICA=1.
IF (CONTINEN NE 3) AMERICA=0.
IF (CONTINEN=4) EUROPA=1.
IF (CONTINEN NE 4) EUROPA=0.

FRE AFRICA ASIA AMERICA EUROPA.

CORRELATIONS
  /VARIABLES=tbn pnb AFRICA ASIA AMERICA EUROPA
  /PRINT=TWOTAIL NOSIG
  /MISSING=PAIRWISE .

REGRESSION
  /DESCRIPTIVES MEAN STDDEV CORR SIG N
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS R ANOVA
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN
  /DEPENDENT tbn
  /METHOD=ENTER pnb AFRICA ASIA AMERICA.



GET FILE='relihot.sav'.

GRAPH
  /SCATTERPLOT(BIVAR)=e10a11 WITH c22a23m
  /MISSING=LISTWISE .

** Regresión simple: Valoración sacerdote según edad. (instrucción completa).
REGRESSION
  /DESCRIPTIVES MEAN STDDEV CORR SIG N
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS R ANOVA
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN
  /DEPENDENT c22a23m
  /METHOD=ENTER e10a11
  /RESIDUALS HIST(ZRESID) NORM(ZRESID) /* Normalidad */
  /CASEWISE PLOT(ZRESID)OUTLIERS(3)    /* Autocorrelación */
  /SCATTERPLOT=(*ZRESID,*ZPRED)        /* Linealidad */
               (*ZRESID,e10a11)        /* Heterocedasticidad */
  /SAVE ZRESID.

* Autocrrelación: representación gráfica de ZRESID por caso.
COMPUTE CAS=$CASENUM.
GRAPH /SCATTERPLOT(BIVAR)=cas WITH zre_1.
GRAPH /SCATTERPLOT(BIVAR)=e10a11 WITH zre_1.


** Supuesto de linealidad no hecho por SCarrión.

REGRESSION
  /DEPENDENT c22a23m
  /METHOD=ENTER e10a11
  /SCATTERPLOT=(*zRESID,*zpred).

** Representación Residuos con VI para mostrar heterocedasticidad
   (no se puede pedir por menú).

REGRESSION
  /DESCRIPTIVES MEAN STDDEV CORR SIG N
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS R ANOVA
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN
  /DEPENDENT c22a23m
  /METHOD=ENTER e10a11
  /SCATTERPLOT=(*zRESID,e10a11).

** Representación Residuos para detectar autocorrelación.
REGRESSION
  /DESCRIPTIVES MEAN STDDEV CORR SIG N
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS R ANOVA
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN
  /DEPENDENT c22a23m
  /METHOD=ENTER e10a11
  /CASEWISE=ALL DEPENDENT PRED ZRESID
  /SAVE=ZRESID(zresid).
*     o bien /CASEWISE PLOT(ZRESID) ALL (por menú).

* Para resolver la antigua representación gráfica de ZRESID por caso.
COMPUTE CAS=$CASENUM.
GRAPH
  /SCATTERPLOT(BIVAR)=cas WITH zresid
  /MISSING=LISTWISE .

** Histograma Residuos estandarizados para el supuesto de normalidad.
REGRESSION
  /DEPENDENT c22a23m
  /METHOD=ENTER e10a11
  /RESIDUALS HIST(ZRESID).

** REGRESION MULTIPLE: Valoración sacerdote según edad, ingresos, estudios e ideologia.

** Selecció de variables: Introducció per blocs.
REGRESSION
  /DESCRIPTIVES MEAN STDDEV CORR SIG N
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS R ANOVA CHANGE ZPP
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN
  /DEPENDENT c22a23m
  /METHOD=ENTER e10a11  /METHOD=ENTER e37  /METHOD=ENTER ideologi
  /METHOD=ENTER e21.

** Selección de variables manual: HISTORY.
REGRESSION
  /VARIABLES=e10a11 e37 ideologi e21 c22a23m
  /STATISTICS HISTORY F
  /DEPENDENT c22a23m
  /METHOD=ENTER.

** Selecció de variables: Passos successius.
REGRESSION
  /DESCRIPTIVES
  /DEPENDENT c22a23m
  /METHOD=STEPWISE e10a11 e21 e37 ideologi.